CSVファイルを読み込むにも書き込むにも、UTF-8とShift-JISを分けて考える必要があります。
１つ目はユーザーにフォルダを指定してもらい、CSVを読み込むコードです。
2つ目のコードは、Shift-JISのCSVファイルのデータで、2023を2024に書き替えたい場合のコードとなります。

Sub 複数CSV呼出JIS版()
    Dim Mycsv As Variant, Newbook As Workbook, Opencsv As Workbook
    Dim CountSh As Long, i As Long
    Mycsv = Application.GetOpenFilename( _
        FileFilter:="CSVファイル,*.csv;*.txt", MultiSelect:=True)
        
     If IsArray(Mycsv) Then
         Set Newbook = Workbooks.Add
            CountSh = Newbook.Worksheets.Count
         For i = 1 To UBound(Mycsv)
            Workbooks.OpenText Filename:=Mycsv(i), Origin:=932, StartRow:=1, Comma:=True
    
            Set Opencsv = ActiveWorkbook
            ActiveSheet.Copy After:=Newbook.Worksheets(CountSh)
            ActiveCell.CurrentRegion.Columns.AutoFit
            Opencsv.Close False
         Next i
     End If
End Sub

Sub 複数CSV呼出して修正JIS版()
    Dim Mycsv As Variant, i As Long
    Mycsv = Application.GetOpenFilename( _
        FileFilter:="CSVファイル,*.csv;*.txt", MultiSelect:=True)

    If IsArray(Mycsv) Then
        For i = 1 To UBound(Mycsv)
            Workbooks.OpenText Filename:=Mycsv(i), Origin:=932, _
             StartRow:=1, DataType:=xlDelimited, Comma:=True

         Cells.Replace What:="2023", Replacement:="2024", LookAt:= _
            xlPart, SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
            ReplaceFormat:=False, FormulaVersion:=xlReplaceFormula2

        ActiveWorkbook.Save
        ActiveWindow.Close
         
        Next
    End If
End Sub

ファイルの選択するためのGetOpenFilenameメソッドの書式と引数の説明
Application.GetOpenFilename(FileFilter, FilterIndex, Title, MultiSelect)
ファイルを開くダイアログをマクロの中で使いたい時に、利用するのが、GetOpenFilenameメソッドです。
親オブジェクトは、 Applicationオブジェクトになります。